Compact / Compress Access File using code

Are you asking for help finding a file stored on your system?
If not, I'm not sure what you mean.
Perhaps you could clarify.

This is an example function that I use.

Expand|Select|Wrap|Line Numbers

1. 'CompactDb compacts a remote Access database.
2. Public Function CompactDb(ByVal strDB As String, _
3.                           Optional strPW As String = "") As Boolean
4.     Dim strNewDB As String, strLocale As String
5.  
6.     On Error GoTo ErrorCDB
7.     strNewDB = Replace(strDB, ".Mdb", "New.Mdb")
8.     Call Echo(True, "Compacting '" & strDB & "'.")
9.     If strPW <> "" Then strLocale = ";pwd=" & strPW
10.     If Exist(strNewDB) Then Kill strNewDB
11.     Call DBEngine.CompactDatabase(SrcName:=strDB, _
12.                                   DstName:=strNewDB, _
13.                                   DstLocale:=strLocale, _
14.                                   SrcLocale:=strLocale)
15.     Kill strDB
16.     Name strNewDB As strDB
17.     Call Echo(True, "'" & strDB & "' compacted.")
18.     CompactDb = True
19.     Exit Function
20.  
21. ErrorCDB:
22.     CompactDb = False
23. End Function
24.  
25. 'Exist returns true if strFile exists.
26. '22/05/2003 Rewritten with better code.
27. '20/05/2005 Added finding of R/O, System & Hidden files
28. Public Function Exist(strFile As String, _
29.                       Optional intAttrib As Integer = &H7) As Boolean
30.     Exist = (Dir(PathName:=strFile, Attributes:=intAttrib) <> "")
31. End Function